Der Fallschirmspringer

Freier Fall mit Reibung

H.J. Lüdde

Die Bewegung eines Fallschirmspringers besteht aus zwei Phasen: 1) der 'freie' Fall zu Beginn mit geschlossenem Fallschirm und 2) der gebremste Fall bei geöffnetem Fallschirm.. In beiden Situationen ist der Fallschirmspringer der Luftreibung ausgesetzt, der Sturz also keineswegs ungebremst. Wir wollen annehmen, dass die Luftreibung proportional zur Fallgeschwindigkeit zunimmt (Stokes'sche Reibung). Die Proportionalitätskonstante hängt dann von dem Luftwiderstand des fallenden Körpers ab. Windkanalversuche ergaben, dass der Luftwiderstand ohne Fallschirm im Mittel 0.2 beträgt, während der Luftwiderstand bei geöffnetem Fallschirm 1.56 beträgt. Mal sehen, was passiert, wenn wir bei 2000 Metern das Flugzeug verlassen:

> restart:

> with(plots):

1 ) Vergleich zwischen freiem Fall (ohne Luftreibung) und gebremstem Fall:

> dglx1:=diff(x1(t),t)=v1(t);

> dglv1:=diff(v1(t),t)=-g; # DGL für freien Fall

> dglx2:=diff(x2(t),t)=v2(t);

> dglv2:=diff(v2(t),t)=-g-a*v2(t); # DGL für gebremsten Fall

> f1:=dsolve({dglx1,dglv1,x1(0)=2000,v1(0)=0},{x1(t),v1(t)}); # löse DGL1

> f2:=dsolve({dglx2,dglv2,x2(0)=2000,v2(0)=0},{x2(t),v2(t)}); # löse DGL2

> fx1:=unapply(subs(f1,x1(t)),t,g);

> fv1:=unapply(subs(f1,v1(t)),t,g);

> fx2:=unapply(subs(f2,x2(t)),t,a,g);

> fv2:=unapply(subs(f2,v2(t)),t,a,g);

> figx1:=plot(fx1(t,9.81),t=0..100, color=[green]):

> figx2:=plot(fx2(t,0.2,9.81),t=0..100, color=[blue]):

> display(figx1,figx2,view=[0..50,0..2000],axes=boxed, labels=[t,x],title=` Freier Fall mit (blau) und ohne (grün) Luftreibung x(t): `);

> figv1:=plot(fv1(t,9.81),t=0..100, color=[green]):

> figv2:=plot(fv2(t,0.2,9.81),t=0..100, color=[blue]):

> display(figv1,figv2,view=[0..50,0..-200],axes=boxed,labels=[t,v], title=` Freier Fall mit(blau) und ohne (grün) Luftreibung v(t): `);

Die Figuren zeigen im Vergleich den freien Fall mit (blau) und ohne (grün) Reibung. Während im freie Fall ohne Reibung die Geschwindigkeit linear mit der Zeit zunimmt, wird im gebremsten Fall eine maximale Endgeschwindigkeit erreicht, abhängig vom Luftwiderstand a.

a) Berechnen Sie die Aufschlagzeiten und Endgeschwindigkeiten für beide Situationen.

b) Betrachten Sie die Ergebnisse für verschiedene Anfangsgeschwindigkeiten (das Flugzeug sinkt bzw. steigt zur Zeit t=0).

2) Sprung mit geöffnetem Fallschirm:

Wir betrachten jetzt die zwei Phasen des Fallschirmsprunges und werden annehmen, dass nach 35s freiem Fall die Reißleine gezogen wird.

> figv2a:=plot(fv2(t,0.2,9.81),t=35..100, color=[blue]):

> figv3:=plot(fv2(t,1.56,9.81),t=0..35, color=[cyan]):

> fv23:=unapply(piecewise(t<=35 , fv2(t,0.2,9.81) , 35<t , fv2(t,1.56,9.81) ),t):

> figv4:=plot(fv23(t,0.2,9.81),t=0..100, color=[red]):

> display(figv2a,figv3,figv4,view=[0..50,0..-50],axes=boxed,labels=[t,v], title=` Gebremster Fall: Phase 1 (blau), Phase 2 (cyan) v(t): `);

a) Welche Endgeschwindigkeit erreicht der Springer bei Bodenberührung?

b) In welcher Höhe hat der Springer die Reißleine gezogen?

c) Wann berührt der Fallschirmspringer den Boden?

Nach unserem Modell ändert sich zur Zeit t=35 die Geschwindigkeit instantan (rote Kurve). Das könnte für unseren Fallschirmspringer äußerst unangenehm werden, da eine so starke instantane Beschleunigung mit ziemlicher Sicherheit zu tödlichen inneren Verletzungen führt, noch bevor der Springer den Boden berührt (siehe Übung d))!

Trotzdem funktioniert doch das Fallschirmspringen! Was ist an unserem Modell falsch?

Wir haben nicht berücksichtigt, dass zwischen dem Ziehen der Reißleine und dem Öffnen des Fallschirms einige Zeit (sagen wir 3s) durch das Entfalten des Schirmes vergeht, in der der Luftwiderstand kontinuierlich zunimmt und somit das Abbremsen abmildert. Wir definieren eine Funktion für den Luftwiderstand l(t), indem wir annehmen, dass der Luftwiderstand zwischen den Extremwerten linear zunimmt:

> t0:=35:

> dt:=3:

> a:=1.36/dt:

> l:=unapply(piecewise(t<t0, 0.2, t0<=t and t<=t0+dt, a*(t-t0)+ 0.2, t>t0+dt, 1.56),t);

> dglx3:=diff(x3(t),t)=v3(t);

> dglv3:=diff(v3(t),t)=-9.81-l(t)*v3(t); # DGL für realistischen Fallschirmsprung

> f3:=dsolve({dglx3,dglv3,x3(0)=2000,v3(0)=0},{x3(t),v3(t)},type=numeric): # löse DGL numerisch mit Runge-Kutta-Fehlberg

> odeplot(f3,[t,x3(t)],0..150,view=[0..110,0..2000],color=blue,labels=[t,x],axes=boxed, title=` x(t) für realistischen Fallschirmsprung `);

> odeplot(f3,[t,v3(t)],0..150,view=[0..110,0..-50],color=blue,labels=[t,v],axes=boxed, title=` v(t) für realistischen Fallschirmsprung `);

> odeplot(f3,[t,-9.81-l(t)*v3(t)],0..150,view=[0..50,-10..20],color=blue,labels=[t,B],axes=boxed,numpoints=1000, title=` Beschleunigung für realistischen Fallschirmsprung `);

>

Man sieht, dass die Beschleunigung in der Phase 1 zunächst von -g auf 0 reduziert wird. Dann entfaltet sich der Fallschirm. In diesen 3 Sekunden wird der Springer um maximal 1.8g gebremst, eine Beschleunigung, die zwar nicht angenehm aber ungefährlich ist. In der Phase 2 reduziert sich die Beschleunigung schnell wieder auf 0 und der Springer segelt mit der konstanten Endgeschwindigkeit von ca 6m/s gen Erdoberfläche. Die Modellierung der Öffnung des Fallschirmes ist also ganz wesentlich für das Wohlbefinden unseres Fallschirmspringers.

d) Untersuchen Sie die Ergebnisse unter verschiedenen Bedingungen für die Öffnungsphase des Fallschirmes: Verkürzen Sie insbesondere die Öffnungsphase.

>