Allerlei Luftreibung

Luftverdrängung durch Bewegung

H.J. Lüdde

nach

N.J. Giordano, Computational Physics, Kapitel 2

Die Bewegung eines Körpers in einem Medium wird erschwert durch die Reibung, die der Bewegungsrichtung entgegenwirkt und mit wachsender Geschwindigkeit ansteigt. Dabei muss der Körper z.B. Luft verdrängen, was Energie kostet, die der kinetischen Bewegungsenergie verloren geht.

In diesem Arbeitsblatt sollen einige typische Bewegungsformen unter der Wirkung von Luftreibung diskutiert werden: 1) die maximale Geschwindigkeit, die ein Fahrradfahrer bei bestimmter konstanter Leistungsabgabe erreichen kann, 2) die Weite einer Kanonenkugel (Wurf mit Reibung) und 3) die Auswirkung von Luftreibung auf Ballspiele (Freistoßtechniken beim Fußball).

1) Maximale Geschwindigkeit eines Fahrradfahrers

Der für die Mechanik übliche Ausgangspunkt, das Newton'sche Kraftgesetz dv/dt=F/m ist zu kompliziert für die Berechnung von v, da die mechanische Umsetzung der Kraft im Fahrrad analytisch aufwendig ist. Wesentlich einfacher dagegen ist die Bestimmung der Leistung P, die ein Fahrradfahrer unter Dauerbelastung abgeben kann (ca 400W). Die Leistung ist definiert als zeitliche Änderung der Energie E des Systems Fahrer und Rad, wobei wir annehmen wollen, dass alle Kugellager optimal geschmiert sind, d.h. keine mechanischen Reibungsverluste auftreten. Die Energie ist somit bei ebener Fahrt (ohne Luftreibung)

----> = P

> restart:

> with(plots):

> dgl1:=diff(v(t),t)=P/(m*v(t)); # Reibungsfreie Bewegung

> sol1:=dsolve({dgl1,v(0)=v0},{v(t)}): # Allgemeine Lösung von dgl1

> fsol1:=unapply(subs(sol1,v(t)),t,v0,P,m);

Ein Fahrradfahrer im Vakuum würde somit bei konstanter Leistungsabgabe mit der Zeit immer schneller werden, ein Ergebnis das mancher leidvollen Erfahrung aus der Praxis widerspricht.

Nun berücksichtigen wir den Luftwiderstand. Empirisch findet man

Bei kleinen Geschwindigkeiten (v < 0.24 m/s) dominiert der lineare Term (Reibung nach Stokes), bei größeren (0.24 m/s < v < 330 m/s) der quadratische Term (Reibung nach Newton). Im Bereich der Schallgeschwindigkeit ist der Luftwiderstand eine kompliziertere Funktion von v, jedoch jenseits von v = 600 m/s wieder linear. a und b hängen von der Form und Materialeigenschaft des bewegten Körpers ab und sind in der Regel nur empirisch zu bestimmen. Für eine Kugel mit Durchmesser d findet man z.B. dass a~d und b~d^2 ist. b ist also proportional zur Querschnittsfläche des bewegten Körpers. Weiterhin findet man, dass b auch von der Dichte des verdrängten Mediums abhängt. Somit haben wir für die Stokes'sche Reibung

> Fr:=unapply(-c*rho*A*v(t)^2,v,c,rho,A);

Dabei entspricht A dem luftverdrängenden Querschnitt des bewegten Körpers (Fahrradfahrer in Rennhaltung: A = 0.33 ), der Dichte des verdrängten Mediums (Luft = 1.293 kg in Meereshöhe) und c dem Reibungskoeffizient (in der Regel kompliziert aber etwa c = 0.5)

> P:='P':

> rho:='rho':

> A:='A':

> c:='c':

> m:='m':

> dgl2:=diff(v1(t),t)=P/(m*v1(t))+Fr(v1,c,rho,A)/m; # Ebene Strecke mit Luftreibung

> P:=200:

> rho:=1.293:

> A:=0.33:

> c:=0.5:

> m:=70:

> sol2:=dsolve({dgl2,v1(0)=0.1},{v1(t)},type=numeric): # Numerische Lösung von dgl2

> fv:=plot(fsol1(t,0,400,70),t=0..100, color=[green]):

> fv1:=odeplot(sol2,[t,v1(t)],0..100,numpoints=500,color=blue):

> display(fv,fv1,view=[0..100,0..40],axes=boxed,labels=[t,v], title=` Geschwindigkeit mit (blau) und ohne (grün) Reibung `);

a) Diskutieren Sie das Ergebnis und bestimmen Sie die Maximalgeschwindigkeit des Fahrradfahrers.

b) Warum muss bei der numerischen Lösung in sol2 eine Anfangsgeschwindigkeit vorgegeben werden? Ist die Maximalgeschwindigkeit davon abhängig?

c) Variieren Sie P und A und entwickeln Sie eine sich daraus ergebende Rennstrategie.

Die bisherigen Überlegungen gelten für eine Fahrt in ebenem Gelände. Entlang einer Gefällstrecke (10% Neigung entsprechen ) hilft der Hangabtrieb ( ) eine höhere Endgeschwindigkeit zu erreichen:

> g:='g':

> P:='P':

> rho:='rho':

> A:='A':

> c:='c':

> m:='m':

> alpha:='alpha':

> dgl2:=diff(v1(t),t)=P/(m*v1(t))+Fr(v1,c,rho,A)/m; # Ebene Strecke

> dgl3:=diff(v2(t),t)=P/(m*v2(t))+g*sin(alpha)+Fr(v2,c,rho,A)/m; # Talfahrt

> g:=9.81:

> P:=400:

> rho:=1.293:

> A:=0.33:

> c:=0.5:

> m:=70:

> alpha:=arctan(0.1):

> sol2:=dsolve({dgl2,v1(0)=0.1},{v1(t)},type=numeric): # Numerische Lösung von dgl2

> sol3:=dsolve({dgl3,v2(0)=0.1},{v2(t)},type=numeric): # Numerische Lösung von dgl3

> fv1:=odeplot(sol2,[t,v1(t)],0..100,numpoints=500,color=blue):

> fv2:=odeplot(sol3,[t,v2(t)],0..100,numpoints=500,color=red):

> display(fv1,fv2,view=[0..100,0..40],axes=boxed,labels=[t,v], title=` Geschwindigkeit ohne (blau) und mit(rot) Gefälle `);

d) Variieren Sie P, A und und entwickeln Sie daraus eine neue Rennstrategie.

Und jetzt gehts bergauf!

> g:='g':

> P:='P':

> rho:='rho':

> A:='A':

> c:='c':

> m:='m':

> alpha:='alpha':

> dgl2:=diff(v1(t),t)=P/(m*v1(t))+Fr(v1,c,rho,A)/m; # Ebene Strecke

> dgl3:=diff(v2(t),t)=P/(m*v2(t))+g*sin(alpha)+Fr(v2,c,rho,A)/m; # Talfahrt

> dgl4:=diff(v3(t),t)=P/(m*v3(t))-g*sin(alpha)+Fr(v3,c,rho,A)/m; # Bergfahrt

> g:=9.81:

> P:=400:

> rho:=1.293:

> A:=0.33:

> c:=0.5:

> m:=70:

> alpha:=arctan(0.1):

> sol2:=dsolve({dgl2,v1(0)=0.1},{v1(t)},type=numeric): # Numerische Lösung von dgl2

> sol3:=dsolve({dgl3,v2(0)=0.1},{v2(t)},type=numeric): # Numerische Lösung von dgl3

> sol4:=dsolve({dgl4,v3(0)=0.1},{v3(t)},type=numeric): # Numerische Lösung von dgl4

> fv1:=odeplot(sol2,[t,v1(t)],0..100,numpoints=500,color=blue):

> fv2:=odeplot(sol3,[t,v2(t)],0..100,numpoints=500,color=red):

> fv3:=odeplot(sol4,[t,v3(t)],0..100,numpoints=500,color=magenta):

> display(fv1,fv2,fv3,view=[0..100,0..40],axes=boxed,labels=[t,v], title=` Geschwindigkeit ohne (blau), mit(rot) Gefälle oder Steigung (magenta) `);

e) Was ergibt sich als Gesamtbild aus dem Vergleich der drei Bewegungsformen für Ihre nächste Fahrradtour?

2) Kanonenkugel

In diesem Abschnitt diskutieren wir ein martialisches Thema: die zweidimensionale Trajektorie einer Kanonenkugel unter dem Einfluss des Luftwiderstandes. Da die Reibungskraft immer entgegen der Bewegungsrichtung wirkt, muss man bei einer mehrdimensionalen Bewegung die Kraft in ihre kartesischen Komponenten zerlegen. Ist der Abschusswinkel, so gilt

.

Wir setzen für die Konstanten a und b

wobei d der Durchmesser der Kanonenkugel ist. Das Beispiel wird für Newton's Ansatz gerechnet. Machen Sie das Gleiche für den Ansatz nach Stokes.

> restart:

> with(plots):

a) Kanonenkugel ohne Reibung

> g:='g':

> v:='v':

> dglx:=diff(x(t),t)=vx(t);

> dglvx:=diff(vx(t),t)=0;

> dgly:=diff(y(t),t)=vy(t);

> dglvy:=diff(vy(t),t)=-g;

> g:=9.81:

> v0:=700: # Betrag der Abschussgeschwindigkeit in [m/s]

> theta:=(Pi/180)*25: # Abschusswinkel

> f1:=array(1..6):

> for i from 1 to 6 do

> theta:=theta+(Pi/180)*5:

> vx0:=v0*cos(theta):

> vy0:=v0*sin(theta):

> sol1:=dsolve({dglx,dglvx,dgly,dglvy, x(0)=0,vx(0)=vx0,y(0)=0,vy(0)=vy0},{x(t),vx(t),y(t),vy(t)},type=numeric): # numerische Losung

> f1[i]:=odeplot(sol1,[x(t),y(t)],0..200,numpoints=500, color=COLOR(RGB, rand()/10^12, rand()/10^12, rand()/10^12)):

> od:

> display(f1[1],f1[2],f1[3],f1[4],f1[5],f1[6],view=[0..60000,0..20000],axes=boxed,labels=[x,y], title=` Kanonenkugel ohne Reibung `);

b) Kanonenkugel mit Reibung nach Newton

> bm:='bm':

> g:='g':

> v:='v':

> dglx:=diff(x(t),t)=vx(t);

> dglvx:=diff(vx(t),t)=-bm*v(t)*vx(t);

> dgly:=diff(y(t),t)=vy(t);

> dglvy:=diff(vy(t),t)=-g-bm*v(t)*vy(t);

> v:=unapply(sqrt(vx(t)^2+vy(t)^2),t):

> g:=9.81:

> bm:=0.00004: # b/m für eine Kugel mit Radius 10 cm

> v0:=700: # Betrag der Abschussgeschwindigkeit in [m/s]

> theta:=(Pi/180)*25: # Abschusswinkel

> f2:=array(1..6):

> for i from 1 to 6 do

> theta:=theta+(Pi/180)*5:

> vx0:=v0*cos(theta):

> vy0:=v0*sin(theta):

> sol1:=dsolve({dglx,dglvx,dgly,dglvy, x(0)=0,vx(0)=vx0,y(0)=0,vy(0)=vy0},{x(t),vx(t),y(t),vy(t)},type=numeric): # numerische Losung

> f2[i]:=odeplot(sol1,[x(t),y(t)],0..100,numpoints=500, color=COLOR(RGB, rand()/10^12, rand()/10^12, rand()/10^12)):

> od:

> display(f2[1],f2[2],f2[3],f2[4],f2[5],f2[6],view=[0..25000,0..10000],axes=boxed,labels=[x,y], title=` Kanonenkugel mit Reibung nach Newton `);

> display(f1[4],f2[3],view=[0..60000,0..15000],axes=boxed,labels=[x,y], title=` Größte Weiten mit und ohne Reibung `);

c) Kanonenkugel mit Reibung nach Newton und Dichtekorrektur nach Höhenformel

> bm:='bm':

> g:='g':

> v:='v':

> rho:='rho':

> dglx:=diff(x(t),t)=vx(t);

> dglvx:=diff(vx(t),t)=-bm*rho(t)*v(t)*vx(t);

> dgly:=diff(y(t),t)=vy(t);

> dglvy:=diff(vy(t),t)=-g-bm*rho(t)*v(t)*vy(t);

> v:=unapply(sqrt(vx(t)^2+vy(t)^2),t):

> rho:=unapply(exp(-y(t)/10000)): # Dichtekorrektur nach Höhenformel

> g:=9.81:

> bm:=0.00004: # b/m für eine Kugel mit Radius 10 cm

> v0:=700: # Betrag der Abschussgeschwindigkeit in [m/s]

> theta:=(Pi/180)*25: # Abschusswinkel

> f3:=array(1..6):

> for i from 1 to 6 do

> theta:=theta+(Pi/180)*5:

> vx0:=v0*cos(theta):

> vy0:=v0*sin(theta):

> sol1:=dsolve({dglx,dglvx,dgly,dglvy, x(0)=0,vx(0)=vx0,y(0)=0,vy(0)=vy0},{x(t),vx(t),y(t),vy(t)},type=numeric): # numerische Losung

> f3[i]:=odeplot(sol1,[x(t),y(t)],0..100,numpoints=500, color=COLOR(RGB, rand()/10^12, rand()/10^12, rand()/10^12)):

> od:

> display(f3[1],f3[2],f3[3],f3[4],f3[5],f3[6],view=[0..30000,0..15000],axes=boxed,labels=[x,y], title=` Kanonenkugel mit Dichtekorrektur `);

> display(f1[4],f2[3],f3[4],view=[0..60000,0..15000],axes=boxed,labels=[x,y], title=` Größte Weiten im Vergleich `);

d) Kanonenkugel mit Dichtekorrektur und Korrektur der Schwerkraft

> bm:='bm':

> R:='R':

> M:='M':

> g:='g':

> v:='v':

> rho:='rho':

> dglx:=diff(x(t),t)=vx(t);

> dglvx:=diff(vx(t),t)=-bm*rho(t)*v(t)*vx(t);

> dgly:=diff(y(t),t)=vy(t);

> dglvy:=diff(vy(t),t)=-g*M/(R+y(t))^2-bm*rho(t)*v(t)*vy(t);

> v:=unapply(sqrt(vx(t)^2+vy(t)^2),t):

> rho:=unapply(exp(-y(t)/10000)): # Dichtekorrektur nach Höhenformel

> R:=6.36*10^6: # Erdradius [m]

> M:=5.95*10^(24): # Masse der Erde [kg]

> g:=6.67*10^(-11): # Gravitationskonstante [m^3/(kg*s^2)]

> bm:=0.00004: # b/m für eine Kugel mit Radius 10 cm

> v0:=700: # Betrag der Abschussgeschwindigkeit in [m/s]

> theta:=(Pi/180)*25: # Abschusswinkel

> f4:=array(1..6):

> for i from 1 to 6 do

> theta:=theta+(Pi/180)*5:

> vx0:=v0*cos(theta):

> vy0:=v0*sin(theta):

> sol1:=dsolve({dglx,dglvx,dgly,dglvy, x(0)=0,vx(0)=vx0,y(0)=0,vy(0)=vy0},{x(t),vx(t),y(t),vy(t)},type=numeric): # numerische Losung

> f4[i]:=odeplot(sol1,[x(t),y(t)],0..100,numpoints=500, color=COLOR(RGB, rand()/10^12, rand()/10^12, rand()/10^12)):

> od:

> display(f4[1],f4[2],f4[3],f4[4],f4[5],f4[6],view=[0..30000,0..15000],axes=boxed,labels=[x,y], title=` Kanonenkugel mit Dichte- und Schwerkraftkorrektur `);

> display(f1[4],f2[3],f3[4],f4[4],view=[0..60000,0..15000],axes=boxed,labels=[x,y], title=` Größte Weiten im Vergleich `);

a) Bestimmen Sie in allen Fällen die Flugzeiten, Endgeschwindigkeiten und optimalen Abschusswinkel.

b) Diskutieren Sie die Ergebnisse und variieren Sie die Anfangsgeschwindigkeit um 10%.

c) Wie verändern sich die Maximalweiten, wenn die Kugel auf einer Höhe von 500 m auftreffen soll?

d) Welche Weiten erreichen Sie bei leichtem Gegenwind (10 km/h)?

3) Fußball

Ich finde es immer wieder faszinierend, wenn ein Freistoßspezialist über eine Distanz von 25-30 m um eine Mauer von Gegenspielern herum, die das Tor für einen geradlinigen Schuss abschirmen, einen Ball im gegnerischen Tor plaziert. Eine 'Banane' wird ein solcher Schuss liebevoll genannt, weil die Flugbahn sichtbar gekrümmt und vom Tormann kaum einschätzbar ist. Wie kommt es zur gekrümmten Flugbahn?

Das zugrunde liegende Phänomen nennt man Magnus Effekt [1,2]. Ein rotierender, bewegter Körper erfährt eine Kraft senkrecht zu seiner Bewegungs- und Drehrichtung

s ist die Kopplungskonstante der Magnus Kraft: Sie ist abhängig von der Rauhigkeit und Ausdehnung der Oberfläche des rotierenden Körpers und natürlich von der Dichte des umgebenden Mediums. Für einen FIFA Fußball (d=21.5 cm, m=500 g), ergibt sich für s=0.0057. Die normale Luftreibung wird wieder quadratisch angenommen, da der Ball deutlich über 24 m/s fliegt. Die Reibungskonstante b-->b/m wird mit einem Wert von 0.027 angenommen. Nun benötigen Sie noch die Daten für ein Tor (Breite 7.32 m, Höhe 2.44 m) und schon können Sie Ihren Freistoß schießen.

a) Schuss aus einer Entfernung von 25 m, Position mittig bezogen auf das Tor. Die Mauer (der Gegenspieler) befindet sich in 9 m Abstand und sei 4m breit. Begründen Sie die folgenden Differentialgleichungen für die Flugbahn des Fußballs und bestimmen Sie und die Anfangsgeschwindigkeit so, dass Sie plaziert in eine der oberen Torecken treffen.

> restart:

> with(plottools):

> with(plots):

> omega:=array(1..3):

> omega[1]='omega[1]':

> omega[2]='omega[2]':

> omega[3]='omega[3]':

> s:='s':

> b:='b':

> g:='g':

> v:='v':

> dglx:=diff(x(t),t)=vx(t); # System von DGL'n

> dgly:=diff(y(t),t)=vy(t);

> dglz:=diff(z(t),t)=vz(t);

> dglvx:=diff(vx(t),t)=-b*v(t)*vx(t)+s*(omega[2]*vz(t)-omega[3]*vy(t));

> dglvy:=diff(vy(t),t)=-g-b*v(t)*vy(t)+s*(omega[3]*vx(t)-omega[1]*vz(t));

> dglvz:=diff(vz(t),t)=-b*v(t)*vz(t)+s*(omega[1]*vy(t)-omega[2]*vx(t));

> v:=unapply(sqrt(vx(t)^2+vy(t)^2+vz(t)^2),t):

> omega[1]:=0: # Winkelgeschwindigkeit des Balls

> omega[2]:=-55:

> omega[3]:=0:

> bM:=4: # Breite der 'Mauer'

> hM:=1.8: # Größe eines Fußballspielers

> xM:=0: # Position des Mittelpunktes der Mauer

> zM:=9:

> bT:=7.52: # Breite eines Fußballtors

> hT:=2.44: # Höhe eines Fußballtors

> xT:=0: # Position des Mittelpunktes des Tors

> zT:=25:

> s:=0.0057: # s/m Kopplungsstärke der Magnuskraft ~d^3 (d=21.5cm)

> b:=0.027: # b/m Reibungskoeffizient ~d^2

> g:=9.81:

> x0:=0: # Anfangsbedingungen

> y0:=0:

> z0:=0:

> vx0:=10.2:

> vy0:=9:

> vz0:=35:

> sol:=dsolve({dglx,dglvx,dgly,dglvy,dglz,dglvz, x(0)=x0,vx(0)=vx0,y(0)=y0,vy(0)=vy0,z(0)=z0,vz(0)=vz0}, {x(t),vx(t),y(t),vy(t),z(t),vz(t)},type=numeric): # numerische Losung

> fsol:=odeplot(sol,[x(t),y(t),z(t)],0..100,numpoints=500, color=blue):

> fTor:=polygon([[bT/2,0,zT],[bT/2,hT,zT],[-bT/2,hT,zT],[-bT/2,0,zT]], color=green):

> fMauer:=polygon([[bM/2,0,zM],[bM/2,hM,zM],[-bM/2,hM,zM],[-bM/2,0,zM]], color=red):

> display(fsol,fTor,fMauer,view=[-5..5,0..10,0..30],orientation=[81,149],axes=boxed,labels=[x,y,z], title=` Trajektorie eines Fußballs `);

b) Interpretieren Sie das Ergebnis. Nehmen wir an, unser Spieler ist ein 'Rechtsfüßler'. Wie musste er dann den Ball treffen: mit dem Außen- oder Innenrist? Welche Zeit benötigt der Ball bis er das Tor trifft?

c) Modifizieren Sie das Arbeitsblatt so, dass auch andere Freistoßsituationen simuliert werden können (Eckball, Freistoß aus spitzem Winkel etc).

d) Simulieren Sie einen 'Heber' über den Tormann. Wie müssen Sie wählen?

Referenzen:

[1] C. Gehrtsen, H.O. Kneser, Vogel: Physik, S 128 ff

[2] G. Joos: Lehrbuch der Theoretischen Physik, S 198 ff; Akademische Verlagsgesellschaft, Frankfurt (1959)