Elastischer Sto\337 unter dem Einfluss der Gravitation

Impuls- und Energieerhaltung

H.J. L\374dde

nach

R.L. Greene: Classical Mechanics with Maple (Springer 1994)

M. Horbatsch: Computational Physics http://www.yorku.ca/marko/

Ein leichter und ein schwerer Ball der Massen m und M fallen in vertikaler Anordnung gemeinsam unter dem Einfluss der Erdanziehung zu Boden (vernachl\344ssige Reibung). Als erster wird der schwere Ball am Boden elastisch gestreut und st\366\337t dann unmittelbar danach mit dem noch fallenden leichten Ball zusammen. Welche Maximalh\366he h erreicht der leichte Ball, wenn beide B\344lle aus der H\366he h0 gestartet werden?

Im Prinzip ist dies der Mechanismus, der bei Novae Explosionen zu den immensen Gasausbr\374chen f\374hrt. In der sp\344ten Sternentwicklung haben sich schwere Elemente (als 'Asche' des Fusionsprozesses) im Inneren eines Sternes angesammelt. Dadurch kommt es zu einer Reduktion der Fusion und der Stern kollabiert unter dem Einfluss seiner eigenen Gravitation. Durch den zunehmenden Druck im Inneren des Sternes wird die Fusion schwererer Elemente wieder 'angefacht', der Stern beginnt wieder zu expandieren. Schwere Elemente aus dem Inneren beginnen sich radial nach au\337en zu bewegen, w\344hrend leichtere Elemente aus der Sternatmosph\344re noch nach innen st\374rzen. Es kommt zu dem oben beschriebenen Sto\337zenario.......

restart:with(plots):

Energie- und Impulserhaltung bestimmen das System der fallenden B\344lle. Zun\344chst bestimmt man die Auftreffgeschwindigkeit der beiden B\344lle, die aus der H\366he h0 zu Boden fallen, aus der Umsetzung von potentieller Energie in kinetische Energie (Energieerhaltung):

E0:=(m+M)*g*h0=(m+M)*v0^2/2;

sol:=solve(E0,v0);

Das Vorzeichen der Geschwindigkeit erh\344lt man durch die Definition eines Koordinatensystems: ist die Koordinatenachse nach oben gerichtet, so gilt:

v0:=-abs(sol[2]);

Jetzt ber\374hrt die erste Masse M den Boden. Da sie elastisch gestreut wird kehrt sich der Impuls um. Unmittelbar danach sto\337en beide B\344lle zusammen (V,v Geschwindigkeiten der B\344lle nach dem Sto\337):

P1:=M*(-v0)+m*v0=M*V+m*v;

E2:=(M+m)/2*v0^2=M/2*V^2+m/2*v^2;

Die kinetische Energie des leichten Balles wird vollst\344ndig in potentielle Energie umgesetzt. Daraus l\344sst sich die maximale Flugh\366he des leichten Balles bestimmen:

E3:=1/2*m*v^2=m*g*h;

Wir haben nun drei Gleichungen (P1,E2,E3) zur Bestimmung der Endgeschwindigkeiten (V,v) und der Endh\366he h:

sol:=solve({E2,E3,P1},h);

Leider geht's nicht so einfach, denn Maple kann nicht wissen, welche L\366sung der quadratischen Gleichung f\374r die Geschwindigkeiten gelten soll:

V:=solve(P1,V);

sol:=solve(E2,v);

An dieser Stelle muss man entscheiden, welche der beiden L\366sungen die physikalisch gew\374nschte ist. Da es sich nicht um die Anfangsgeschwindigkeit handeln kann, w\344hlt man die andere L\366sung und kann sie schlie\337lich zur Bestimmung der maximalen H\366he einsetzen:

v:=sol[1];

h:=solve(E3,h);

Welche H\366he erreicht der leichte Ball maximal?

hmax:=limit(h,M=infinity);

Zeichne die H\366he H(M) des leichten Balles als Funktion der Masse M des schweren Balles:

semilogplot(subs(h0=1,m=1,g=9.81,h),M=1..1000,axes=boxed,color=blue,labels=[M,H],title="H\366he H(M) als Funktion der Masse M des schweren Balles");

Was passiert eigentlich mit dem schweren Ball?

M:='M':

E4:=1/2*M*V^2=M*g*H:

H:=solve(E4,H);

Hmax:=limit(H,M=infinity);

Verstehen Sie das Ergebnis?