Bewegung in homogenen elektromagnetischen Feldern

Hendrik van Hees
04. Juni 2000

Allgemeine Vorbemerkungen

Das elektromagnetische Feld ist in der kovarianten Schreibweise ein antisymmetrischer Tensor, der Faradaytensor. Im folgenden sind alle Vektoren und Tensoren (es kommen nur solche bis zur 2. Stufe vor) mit Indizes oben (kontravariant) zu verstehen. Wir arbeiten mit dem in der Teilchenphysik weitgehend üblichen rationalisierten gaußschen Maßsystem mit c=1 (Heaviside units). Wir folgen in der Definition der relativistischen kovarianten Schreibweise wie sie in Bjorken-Drell steht (was sich auch weitgehend durchgesetzt hat). Auch das Particle Data Booklet hält sich an diese Konvention. Der Fundamentaltensor (Pseudometrik) ist also

g = {{1, 0, 0, 0}, {0, -1, 0, 0}, {0, 0, -1, 0}, {0, 0, 
            0, -1}};

MatrixForm[g]

Der Faradaytensor für ein beliebiges elektromagnetisches Feld liest sich

Evec = {E1, E2, E3}; Bvec = {B1, B2, B3};

F[{E1_, E2_, E3_}, {B1_, B2_, 
            B3_}] = {{0, -E1, -E2, -E3}, {E1, 0, -B3, 
            B2}, {E2, B3, 0, -B1}, {E3, -B2, B1, 0}};

MatrixForm[F[Evec, Bvec]]

Die Bewegungsgleichung wird in vierdimensional kovarianter Gestalt mit der Eigenzeit tau (eine spezielle Wahl eines Weltzeitparameters) geschrieben. Die kovariante Geschwindigkeit heißt u=dx/d(tau).

u[tau_] = {u0[tau], u1[tau], u2[tau], u3[tau]};

Die Bewegungsgleichung lautet (für eine Herleitung vgl. z.B. Landau-Lifshitz Vol. 2)

eom = 
        Table[m D[u[tau], tau][[i]] == 
            q (F[Evec, Bvec] . g . u[tau])[[i]], {i, 1, 
            4}];

MatrixForm[eom]

Darin steht m für die invariante Masse. Eine geschwindigkeitsabhängige Masse, wie sie in älteren Lehrbüchern steht, ist wenig hilfreich, da sie keine relativistisch kovariante Größe ist. Die rechte Seite der Gleichung ist in den drei Raumkomponenten unschwer als die Lorentzkraft in vierdimensional kovarianter Gestalt zu erkennen. Die Bewegungsgleichung ist mit der Bedingung, daß tau die Eigenzeit ist, verträglich, denn es gilt

u[tau] . g . (F[Evec, Bvec] . g . u[tau]) // Simplify

Das bedeutet, daß u.g.u=const. ist. Die Eigenzeit wählen wir nun so, daß sie die Zeit im Ruhsystem des Betrachters ist, so daß u.g.u=1 sein muß. Die Bewegung besitzt also eine Zwangsbedingung 2. Klasse (d.h. eine solche, die nur bei Erfüllung der Bewegungsgleichung gelten muß, aber das ist für die klassische Physik wenig wichtig, erst beim Formalismus der 1. Quantisierung wird das wichtig).

Bewegung im homogenen elektrischen Feld

In diesem Abschnitt soll die Bewegung eines Punktteilchens im homogenen elektrischen Feld dargestellt werden. O.b.d.A. legen wir das elektrische Feld in Richtung der z-Achse.

MatrixForm[F[{0, 0, Ez}, {0, 0, 0}]]

gl = 
        Table[m D[u[tau], tau][[i]] == 
            q (F[{0, 0, Ez}, {0, 0, 0}] . g . u[tau])[[i]], {i, 1, 
            4}];

MatrixForm[gl]

solution = 
      DSolve[gl, {u0[tau], u1[tau], u2[tau], u3[tau]}, tau] // 
        FullSimplify

In dieser Lösung ist die Zwangsbedingung 2. Klasse zu berücksichtigen

u[tau] . g . u[tau] /. Flatten[solution] // FullSimplify

D.h. es muß C[1]^2=1+C[2]^2+C[3]^2+C[4]^2 gelten. Damit weiter u0 stets positiv ist (Bewegung in positive Zeitrichtung muß hier von Hand eingesetzt werden->Bewegungsumkehrinvarianz der elektromagnetischen Wechselwirkung. Die Gleichung zeichnet keine bestimmte Zeitrichtung aus). Die freien Integrationskonstanten C[2], C[3], C[4] sind entsprechend der Anfangsbedingungen für die Vierergeschwindigkeit zu wählen.

usol[
          tau_] = (u[tau] /. Flatten[solution]) /. {C[1] -> 
              Sqrt[1 + C[2]^2 + C[3]^2 + C[4]^2]};

MatrixForm[usol[tau]]

Die Lösung für die Raumzeitkoordinaten ergibt sich durch Integration. Wir legen o.B.d.A. den Anfangspunkt der Bewegung in den Ursprung des Koordinatensystems

x[tau_] = Integrate[usol[tauPrime], {tauPrime, 0, tau}];

MatrixForm[x[tau]]

Jetzt zeigen wir exemplarisch ein paar Ergebnisse

Ez = 1; q = 1; m = 1;

Die Geschwindigkeit v3 in z-Richtung für einen im benutzen Koordinatensystem ruhenden Beobachter ist u3/u0, und natürlich nähert sich diese Geschwindigkeit der Lichtgeschwindigkeit c=1 und überschreitet diese nie:

Plot[usol[tau][[4]]/usol[tau][[1]] /. {C[2] -> 0, 
          C[3] -> 0, C[4] -> 0}, {tau, 0, 5}, 
      PlotRange -> {0, 1}, AxesLabel -> {"τ", "v3"}, 
      PlotStyle -> AbsoluteThickness[2]]

Die Bahnkurve sieht folgendermaßen aus. Hier starten wir mit einer gewissen Anfangsgeschwindigkeit in x-Richtung. Das entspricht Anfangsbedingungen des "waagrechten Wurfes" im nichtrelativistischen Fall wäre das eine Parabel

ParametricPlot[
      Evaluate[{x[tau][[2]], x[tau][[4]]} /. {C[2] -> 
              0.2, C[3] -> 0, C[4] -> 0}], {tau, 0, 2}, 
      AxesLabel -> {"x", "z"}, 
      PlotStyle -> AbsoluteThickness[2], 
      AxesLabel -> {"x", "z"}]

Für eine Anfangsbedingung, die einem schrägen Wurf mit einer Anfangsgeschwindigkeits-z-Komponente in Gegenrichtung zum E-Feld entspricht, sieht das Bild so aus:

ParametricPlot[
      Evaluate[{x[tau][[2]], x[tau][[4]]} /. {C[2] -> 
              0.2, C[3] -> 0, C[4] -> -0.6}], {tau, 0, 2}, 
      PlotStyle -> AbsoluteThickness[2], 
      AxesLabel -> {"x", "z"}]

Bewegung im konstanten Magnetfeld

Clear[q, m, Ez]

In diesem Abschnitt soll die Bewegung eines Punktteilchens im homogenen magnetischen Feld dargestellt werden. O.b.d.A. legen wir das elektrische Feld in Richtung der z-Achse.

MatrixForm[F[{0, 0, 0}, {0, 0, Bz}]]

gl = 
        Table[m D[u[tau], tau][[i]] == 
            q (F[{0, 0, 0}, {0, 0, Bz}] . g . u[tau])[[i]], {i, 1, 
            4}];

MatrixForm[gl]

solution = 
      DSolve[gl, {u0[tau], u1[tau], u2[tau], u3[tau]}, tau] // 
        FullSimplify

In dieser Lösung ist die Zwangsbedingung 2. Klasse zu berücksichtigen

u[tau] . g . u[tau] /. Flatten[solution] // FullSimplify

D.h. es muß C[1]^2=1+C[2]^2+C[3]^2+C[4]^2 gelten. Damit weiter u0 stets positiv ist (Bewegung in positive Zeitrichtung muß hier von Hand eingesetzt werden->Bewegungsumkehrinvarianz der elektromagnetischen Wechselwirkung. Die Gleichung zeichnet keine bestimmte Zeitrichtung aus). Die freien Integrationskonstanten C[2], C[3], C[4] sind entsprechend der Anfangsbedingungen für die Vierergeschwindigkeit zu wählen.

usol[
          tau_] = (u[tau] /. Flatten[solution]) /. {C[1] -> 
              Sqrt[1 + C[2]^2 + C[3]^2 + C[4]^2]};

MatrixForm[usol[tau]]

Die Lösung für die Raumzeitkoordinaten ergibt sich durch Integration. Wir legen o.B.d.A. den Anfangspunkt der Bewegung in den Ursprung des Koordinatensystems

x[tau_] = Integrate[usol[tauPrime], {tauPrime, 0, tau}];

MatrixForm[x[tau]]

Jetzt zeigen wir exemplarisch ein paar Ergebnisse

Bz = 1; q = 1; m = 1;

Die Geschwindigkeitskomponente v1 in x-Richtung für einen im benutzen Koordinatensystem ruhenden Beobachter ist u1/u0. Die Lösung hat oszillatorischen Charakter. Der Grund ist klar: Die Projektion der Bahnkurve auf die xy-Ebene ist ein Kreis. Die Gesamtbewegung i.a. eine Spiralbahn (s. u.). In diesem Fall ist, wie ein Blick auf die Lösung zeigt, die Eigenzeit proportional zur Systemzeit des Beobachters.

Plot[usol[tau][[2]]/usol[tau][[1]] /. {C[2] -> 
            0.2, C[3] -> 0, C[4] -> 0}, {tau, 0, 10}, 
      AxesLabel -> {"τ", "x"}, 
      PlotStyle -> AbsoluteThickness[2]]

Die Bahnkurve in xy-Ebene sieht folgendermaßen aus. Hier starten wir mit einer gewissen Anfangsgeschwindigkeit in x-Richtung. In der Tat beschreibt das Teilchen eine Kreisbahn, wie entsprechend der Lorentzkraft im puren Magnetfeld zu erwarten war: Die Kraft wirkt in jedem Moment senkrecht zur Geschwindigkeit!

ParametricPlot[
      Evaluate[{x[tau][[2]], x[tau][[3]]} /. {C[
                2] -> -0.2, C[3] -> 0, C[4] -> 0}], {tau, 
        0, 7}, AspectRatio -> 1, AxesLabel -> {"x", "y"}, 
      PlotStyle -> AbsoluteThickness[2]]

Für eine allgemeine Anfangsbedingung lohnt sich ein 3-dim-Plot, denn i.a. ist die Bahnkurve eine Schraubenlinie konstanter Ganghöhe (die Geschwindigkeit in Richtung des Magnetfeldes bleibt konstant, weil die Kraft stets senkrecht zur Geschwindigkeit und zum Magnetfeld wirkt F_mag=q v × B).

ParametricPlot3D[
      Evaluate[{x[tau][[2]], x[tau][[3]], x[
                tau][[4]]} /. {C[2] -> 0.5, C[3] -> 0, 
            C[4] -> 0.1}], {tau, 0, 20}, AspectRatio -> 1, 
      ViewPoint -> {2.895,  1.108,  1.356}, 
      AxesLabel -> {"x", "y", "z"}]

Bewegung im gekreuzten E- und B-Feld

Clear[q, m, Ez, Bz]

In diesem Abschnitt soll die Bewegung eines Punktteilchens im homogenen elektrischen Feld (in y-Richtung) magnetischem Feld (in z-Richtung) dargestellt werden.

MatrixForm[F[{0, Ey, 0}, {0, 0, Bz}]]

gl = 
        Table[m D[u[tau], tau][[i]] == 
            q (F[{0, Ey, 0}, {0, 0, Bz}] . g . u[tau])[[i]], {i, 1, 
            4}];

MatrixForm[gl]

solution = 
        DSolve[gl, {u0[tau], u1[tau], u2[tau], u3[tau]}, tau] // 
          FullSimplify;

In dieser Lösung ist die Zwangsbedingung 2. Klasse zu berücksichtigen

u[tau] . g . u[tau] /. Flatten[solution] // FullSimplify

D.h. es muß C[1]^2=1+C[2]^2+C[3]^2+C[4]^2 gelten. Damit weiter u0 stets positiv ist (Bewegung in positive Zeitrichtung muß hier von Hand eingesetzt werden->Bewegungsumkehrinvarianz der elektromagnetischen Wechselwirkung. Die Gleichung zeichnet keine bestimmte Zeitrichtung aus). Die freien Integrationskonstanten C[2], C[3], C[4] sind entsprechend der Anfangsbedingungen für die Vierergeschwindigkeit zu wählen.

usol[
          tau_] = (u[tau] /. Flatten[solution]) /. {C[1] -> 
              Sqrt[1 + C[2]^2 + C[3]^2 + C[4]^2]};

usol[tau]

Die Lösung für die Raumzeitkoordinaten ergibt sich durch Integration. Wir legen o.B.d.A. den Anfangspunkt der Bewegung in den Ursprung des Koordinatensystems

x[tau_] = Integrate[usol[tauPrime], {tauPrime, 0, tau}];

Leider erlaubt das Exportieren nach ps bzw. html nicht die Benutzung von MatrixForm für so lange Ausdrücke, weil die Ausgabe einfach abgeschnitten wird: ;-((

x[tau]

Jetzt zeigen wir exemplarisch ein paar Ergebnisse

Ey = 0.5; Bz = 1; q = 1; m = 1;

Die Geschwindigkeitskomponente v1 in x-Richtung für einen im benutzen Koordinatensystem ruhenden Beobachter ist u1/u0. Die Lösung hat oszillatorischen Charakter. Der Grund ist klar: Die Projektion der Bahnkurve auf die xy-Ebene ist ein Kreis. Die Gesamtbewegung i.a. eine Spiralbahn (s. u.). In diesem Fall ist, wie ein Blick auf die Lösung zeigt, die Eigenzeit proportional zur Systemzeit des Beobachters.

Plot[usol[tau][[2]]/usol[tau][[1]] /. {C[2] -> 
            0.2, C[3] -> 0, C[4] -> 0}, {tau, 0, 10}, 
      AxesLabel -> {"τ", "x"}, 
      PlotStyle -> AbsoluteThickness[2]]

Die Bahnkurve in xy-Ebene sieht folgendermaßen aus. Hier starten wir mit einer gewissen Anfangsgeschwindigkeit in x-Richtung.

ParametricPlot[
      Evaluate[{x[tau][[2]], x[tau][[3]]} /. {C[
                2] -> -0.2, C[3] -> 0, C[4] -> 0}], {tau, 
        0, 20}, AspectRatio -> 1, AxesLabel -> {"x", "y"}, 
      PlotStyle -> AbsoluteThickness[2]]

Für eine allgemeine Anfangsbedingung lohnt sich ein 3-dim-Plot. Die Anfangsbedingungen wurden so gewählt, daß eine einigermaßen ansehnliche Bahnkurve entsteht. Besitzer von Mathematica sollten ein wenig mit diesem Notebook spielen ;-)).

Sqrt[3*0.3^2]

ParametricPlot3D[
      Evaluate[{x[tau][[2]], x[tau][[3]], x[
                tau][[4]]} /. {C[2] -> -0.01, 
            C[3] -> 0.5, C[4] -> 0.3}], {tau, 0, 20}, 
      AxesLabel -> {"x", "y", "z"}, 
      ViewPoint -> {2.885,  -1.269,  1.231}]