Die freie Schwarzschildlösung

Allgemeinster kugelsymmetrischer Ansatz für die Metrik

q={t,r,th,ph};

g={{l[r,t],a[r,t]/2,0,0},{a[r,t]/2,h[r,t],0,0},{0,0,k[r,t],0},{0,0,0,k[r,t]Sin[th]^2}};

MatrixForm[g]

dq={dt,dr,dth,dph};

FullSimplify[dq.g.dq]

Durch geeignete Umparametrisierung von r und t können wir die Außerdiagonalelemente zum Verschwinden bringen und k=-r^2 setzen:

h[r_,t_]=-Exp[la[r,t]];l[r_,t_]=c^2 Exp[nu[r,t]];a[r_,t_]=0;k[r_,t_]=-r^2;

FullSimplify[dq.g.dq]

gcontra=Inverse[g];

Wir lassen und als nächstes die Christoffelsymbole für den Riemannschen affinen Zusammenhang aus der Definition durch Ableitungen der Metrik ausrechnen:

christ=Table[Table[Sum[1/2gcontra[[ii]][[mi]](D[g[[mi]][[ki]],q[[li]]]+D[g[[mi]][[li]],q[[ki]]]-D[g[[ki]][[li]],q[[mi]]]),{mi,1,4}],{ki,1,4},{li,1,4}],{ii,1,4}];

Do[Print[MatrixForm[christ[[ii]]]],{ii,1,4}]

Daraus ergibt sich sofort für den Ricci-Tensor (vollständig kovariante Komponenten)

RicciTen=FullSimplify[Table[Sum[D[christ[[li]][[ii]][[ki]],q[[li]]]-D[christ[[li]][[ii]][[li]],q[[ki]]]+Sum[christ[[li]][[ii]][[ki]] christ[[mi]][[li]][[mi]]-christ[[mi]][[ii]][[li]] christ[[li]][[ki]][[mi]],{mi,1,4}],{li,1,4}],{ii,1,4},{ki,1,4}]]

Die freien Einstein-Hilbert-Gleichungen verlangen, daß dieser Tensor verschwindet. Für die (01)- bzw. (10)-Komponente folgt daraus

la[r_,t_]=la[r];

Lassen wir uns die daraus folgenden Vereinfachungen für den Riccitensor anzeigen:

FullSimplify[RicciTen]

Durch Kombination der Gleichungen für die (00)- und die (11)-Komponente folgt, daß nu+lambda=f(t) ist. Diese Funktion f(t) können wir durch die noch freigestellte Umparametrisierung der Zeit t=t(t’) zum Verschwinden bringen. Es ist also

nu[r_,t_]=nu[r];la[r_]=-nu[r];

Der Ricci-Tensor vereinfacht sich dadurch gleich nochmals drastisch:

FullSimplify[RicciTen]

Lösen wir weiter zuerst die Gleichung für die (22)-Komponente (dann ist offenbar auch die Gleichung für die (11)-Komponente automatisch erfüllt:

DSolve[RicciTen[[3]][[3]]==0,nu[r],r]

In der üblichen Notation mit dem Schwarzschildradius als Parameter ist

nu[r_]=Log[1-rs/r]

Jetzt müssen wir noch nachprüfen, ob damit auch die verbleibenden Componenten des Ricci-Tensors verschwinden, so daß wir wirklich eine Lösung der Einstein-Hilbertgleichungen für das Vakuum gefunden haben

FullSimplify[RicciTen]

Lassen wir uns also nochmal die endgültige Metrik in der Form des invarianten Viererlängenelements ausgeben

dq.g.dq

Das war historisch die erste exakte Lösung der freien Einstein-Hilbert-Gleichungen für das Gravitationsfeld im Rahmen der ART und wurde 1916 von Karl Schwarzschild gefunden. Daß die vermeintliche Singularität bei r=rs nur eine Koordinatensingularität ist, sieht man unter anderem daran, daß die Determinante

Det[g]

bei r=rs nicht singulär wird. Die Schwarzschildlösung besitzt nur bei r=0 eine echte Raumzeit-Singularität. Das kann man durch die Koordinatentransformation zu Kruskal-Koordinaten zeigen (vgl. z.B. das Lehrbuch von E. Rebhan, Bd. 6). Auch die Singularität der Metrik entlang der “z-Achse” (entsprechend th=0 bzw. th=Pi) ist nur die übliche Koordinateningularität von Kugelkoordinaten. 

Für gewöhnliche Himmelskörper tritt i.a. kein Problem beim Schwarzschildradius auf, weil dieser im Inneren der Körper gilt, wo man die Schwarzschildlösung für die Einstein-Hilbert-Gleichungen mit Materie aufsuchen muß. Ein Beispiel ist die Oppenheimer-Tolman-Volkoff-Lösung für statische Sterne. Dabei ergibt sich als Stabilitätskriterium, daß der Schwarzschildradius im Sterninneren liegen muß (s. wieder Rebhan, Bd. 6). Objekte, für die dies nicht erfüllt ist, sind ein schwarzes Loch, also eine punktförmige Singularität der Raumzeit, die nach dem sog. “no-hair theorem” von Wheeler im Rahmen der reinen ART-Maxwell-Theorie keinerlei Charakteristica als deren fundamentale Paramater (Masse, elektrische Ladung, Drehimpuls) aufweist.