V7.html

Zum Maple Worksheed

Theoretische Physik 3 für Lehramt L3

Quantenmechanik, Spezielle Relativitätstheorie und weitere Gebiete der Theoretischen Physik

Vorlesung gehalten an der J.W.Goethe-Universität in Frankfurt am Main (Wintersemester 2016/17)

von Prof. Dr.Dr.h.c. Horst Stöcker und Dr.phil.nat. Dr.rer.pol. Matthias Hanauske

Frankfurt am Main 17.10.2016

Erster Vorlesungsteil: Quantenmechanik

Kapitel I: 2.5) Der Tunneleffekt

Der Tunneleffekt

> restart:
with(plots):

Wir betrachten im folgenden einen quantenmechanischen Zustand eines Teilchens, welcher durch einen Potentialwall tunnelt und wir beschränken uns zunächst auf eine räumliche Dimension. Der Potentialtopf besitz das folgende Aussehen:

> V:=piecewise(x <0, 0, x >=0 and x <=d, V0 ,x >d, 0);
setd:=1;
setV0:=10;
plot(subs({d=setd,V0=setV0},V),x=-5..5,thickness=3,view=0..15,title="Potentialwall");

piecewise(`<`(x, 0), 0, `and`(`<=`(0, x), `<=`(x, d)), V0, `<`(d, x), 0)

Plot_2d

Da der Hamiltonoperator dieses Systems nicht von der Zeit abhängt, vereinfacht sich die Schrödingergleichung. Wir betrachten nun einen Zustand des Teichens und beschränken uns auf 0<E<V0. Klassisch könnte ein solches Teilchen niemals die Potentialbarriere überwinden. Die Schrödingergleichung unterteilt sich in drei separate Bereiche. Die Schrödingergleichung links vom Potentialtopf (x < 0 ) lautet:

> SGLLinks:=diff(psi[L](x),x,x)=-2*m*E/hq^2*psi[L](x);
SGLLinks:=diff(psi[L](x),x,x)=-k^2*psi[L](x):

(1.1)

Im inneren Bereich der Potentialbariere (0<x<d) lautet sie:

> SGLInnen:=diff(psi[M](x),x,x)=2*m*(V0-E)/hq^2*psi[M](x);
SGLInnen:=diff(psi[M](x),x,x)=alpha^2*psi[M](x):

(1.2)

Im rechten Bereich (x>d) lautet sie hingegen:

> SGLRechts:=diff(psi[R](x),x,x)=-2*m*E/hq^2*psi[R](x);
SGLRechts:=diff(psi[R](x),x,x)=-k^2*psi[R](x):

(1.3)

Wir setzen k=sqrt(2*m*E)/hq und alpha=sqrt(2*m*(V0-E))/hq). Die Lösung im linken Bereich stellt eine sowohl einlaufende als auch auslaufende (reflektierte) ''de Broglieschen" Materiewelle dar, wohingegen im rechten Bereich (x>d) nur eine auslaufende Welle existiert. Im mittleren Bereich der Potentialbariere (0<x<d) sind jedoch beide Lösungen zulässig:

> Loes1:=A*exp(I*k*x) +B*exp(-I*k*x);
Loes2:=C*exp(alpha*x) +D*exp(-alpha*x);
Loes3:=F*exp(I*k*x);

(1.4)

An den Grenzbereichen (x=0 und x=d) müssen die Zustandsfunktionen stetig und glatt ineinander übergehen:

> Eq1:=eval(subs(x=0,Loes1))=eval(subs(x=0,Loes2));
Eq2:=eval(subs(x=0,diff(Loes1,x))=eval(subs(x=0,diff(Loes2,x))));
Eq3:=eval(subs(x=d,Loes2))=eval(subs(x=d,Loes3));
Eq4:=eval(subs(x=d,diff(Loes2,x))=eval(subs(x=d,diff(Loes3,x))));

(1.5)

Diese vier Gleichungen kann man mittels algebraischer Operationen wie folgt umformen:

> EqC:=C=simplify(solve(subs(F=solve(Eq3,F),Eq4),C));
EqF:=F=simplify(solve(subs(C=simplify(solve(subs(F=solve(Eq3,F),Eq4),C)),Eq3),F));
EqA:=A=simplify(expand(subs(C=simplify(solve(subs(F=solve(Eq3,F),Eq4),C)),solve(subs(B=solve(Eq1,B),Eq2),A))));
EqB:=B=simplify(expand(subs(C=simplify(solve(subs(F=solve(Eq3,F),Eq4),C)),solve(subs(A=solve(Eq1,A),Eq2),B))));

(1.6)

Die noch freie Amplitude D beschreibt die Intensität des Materiestrahls, wir setzten diese im Folgenden auf D=1. Wir setzten zusätzlich m=hq=1, V0=10, E=8 und d=1. Die Zustandsfunktion läßt sich dann in den einzelnen Bereichen als eine komplexwertige Funktion von x angeben

> setd:=1;
setD:=1;
setV0:=10;
setE:=8;
setk:=subs({m=1,hq=1,E=setE},sqrt(2*m*E)/hq);
setalpha:=subs({m=1,hq=1,E=setE,V0=setV0},sqrt(2*m*(V0-E))/hq);
Loes1a:=evalf(subs({d=setd,D=setD,alpha=setalpha,k=setk},subs({A=rhs(EqA),B=rhs(EqB)},Loes1)));
Loes2a:=evalf(subs({d=setd,D=setD,alpha=setalpha,k=setk},subs({C=rhs(EqC)},Loes2)));
Loes3a:=evalf(subs({d=setd,D=setD,alpha=setalpha,k=setk},subs({F=rhs(EqF)},Loes3)));

(1.7)

und darstellen (gepunktete Funktion stellt den Imaginärteil dar):

> PLL:=plot({Re(Loes1a)},x=-3..0,color=black,thickness=2):
PLM:=plot({Re(Loes2a)},x=0..setd,color=blue,thickness=2):
PLR:=plot({Re(Loes3a)},x=setd..3,color=red,thickness=2):
PLLIM:=plot({Im(Loes1a)},x=-3..0,color=black,thickness=2,linestyle=2):
PLMIM:=plot({Im(Loes2a)},x=0..setd,color=blue,thickness=2,linestyle=2):
PLRIM:=plot({Im(Loes3a)},x=setd..3,color=red,thickness=2,linestyle=2):
display(PLL,PLM,PLR,PLLIM,PLMIM,PLRIM);

Plot_2d

Die Warscheinlichkeitsdichte besitzt das folgende Aussehen:

> PLL:=plot({Re(conjugate(Loes1a)*Loes1a)},x=-3..0,color=black,thickness=2):
PLM:=plot({Re(conjugate(Loes2a)*Loes2a)},x=0..setd,color=blue,thickness=2):
PLR:=plot({Re(conjugate(Loes3a)*Loes3a)},x=setd..3,color=red,thickness=2):
display(PLL,PLM,PLR);

Plot_2d

In dieser Animation wird die Breite des Potentialwalls variiert:

> Loes1a:=evalf(subs({D=setD,alpha=setalpha,k=setk},subs({A=rhs(EqA),B=rhs(EqB)},Loes1))):
Loes2a:=evalf(subs({D=setD,alpha=setalpha,k=setk},subs({C=rhs(EqC)},Loes2))):
Loes3a:=evalf(subs({D=setD,alpha=setalpha,k=setk},subs({F=rhs(EqF)},Loes3))):
for dd from 1 by 1 to 50 do
setd:=0.03*dd+0.1:
PLL:=plot({Re(subs(d=setd,Loes1a))},x=-3..0,color=black,thickness=2):
PLM:=plot({Re(subs(d=setd,Loes2a))},x=0..setd,color=blue,thickness=2):
PLR:=plot({Re(subs(d=setd,Loes3a))},x=setd..3,color=red,thickness=2):
PLLIM:=plot({Im(subs(d=setd,Loes1a))},x=-3..0,color=black,thickness=2,linestyle=2):
PLMIM:=plot({Im(subs(d=setd,Loes2a))},x=0..setd,color=blue,thickness=2,linestyle=2):
PLRIM:=plot({Im(subs(d=setd,Loes3a))},x=setd..3,color=red,thickness=2,linestyle=2):
Ani[dd]:=display(PLL,PLM,PLR,PLLIM,PLMIM,PLRIM);
od:

> display([seq(Ani[i],i=1..50)],insequence=true);

Plot_2d

Der Transmissionskoeffizient T ergibt sich durch T=F^2/A^2 und der Reflexionskoeffizient R durch R=B^2/A^2. Stellt man diese beiden Größen als Funktion der Barrierendicke d dar ergibt sich der folgende funktionale Zusammenhang (E=8, T=rot und R=blau). Die gepunktete schwarze Kurve stellt eine Approximation des Transmissionskoeffizient T dar (TApp) (siehe z.B. Schmüser S: 46). Diese Approximation ist jedoch nur gut, falls exp(-2*alpha*d)<<1 ist.

> TApp:=16*(1-E/V0)*E/V0*exp(-2*alpha*d);
setD:=1:
setV0:=10:
setE:=8:
setk:=subs({m=1,hq=1,E=setE},sqrt(2*m*E)/hq):
setalpha:=subs({m=1,hq=1,E=setE,V0=setV0},sqrt(2*m*(V0-E))/hq):
TAppd:=subs(E=setE,subs({alpha=setalpha,V0=setV0},TApp)):
T:=subs({alpha=setalpha,k=setk},simplify(conjugate(rhs(EqF))*rhs(EqF)/(conjugate(rhs(EqA))*rhs(EqA)))):
R:=subs({alpha=setalpha,k=setk},simplify(conjugate(rhs(EqB))*rhs(EqB)/(conjugate(rhs(EqA))*rhs(EqA)))):
PLT:=plot(T,d=0..2,color=red,thickness=2):
PLR:=plot(R,d=0..2,color=blue,thickness=2):
PLTApp:=plot(TAppd,d=0..2,color=black,thickness=2,linestyle=2):
display(PLT,PLR,PLTApp,view=0..1.1);

Plot_2d

Stellt man T und R als Funktion der Energie E dar ergibt sich (d=0.2, T=rot und R=blau):

> setd:=0.2:
setD:=1:
setV0:=10:
setk:=subs({m=1,hq=1},sqrt(2*m*E)/hq):
setalpha:=subs({m=1,hq=1,V0=setV0},sqrt(2*m*(V0-E))/hq):
T:=subs({d=setd,alpha=setalpha,k=setk},simplify(conjugate(rhs(EqF))*rhs(EqF)/(conjugate(rhs(EqA))*rhs(EqA)))):
R:=subs({d=setd,alpha=setalpha,k=setk},simplify(conjugate(rhs(EqB))*rhs(EqB)/(conjugate(rhs(EqA))*rhs(EqA)))):
PLT:=plot(T,E=0.1..9.9,color=red,thickness=2):
PLR:=plot(R,E=0.1..9.9,color=blue,thickness=2):
display(PLT,PLR);

Plot_2d

Die folgende Animation zeigt den Transmissionskoeffizient T und dessen Approximation als Funktion von E und einem Animationsparameter d=[0.1..1]

> setD:=1:
setV0:=10:
setk:=subs({m=1,hq=1},sqrt(2*m*E)/hq):
setalpha:=subs({m=1,hq=1,V0=setV0},sqrt(2*m*(V0-E))/hq):
TAppE:=subs({alpha=setalpha,V0=setV0},TApp):
T:=subs({alpha=setalpha,k=setk},simplify(conjugate(rhs(EqF))*rhs(EqF)/(conjugate(rhs(EqA))*rhs(EqA)))):
PLT:=animate(T,E=0.1..9.2,d=0.1..1,color=red,thickness=2,frames=40):
PLTApp:=animate(TAppE,E=0.1..9.2,d=0.1..1,color=black,thickness=2,linestyle=2,frames=40):
display(PLT,PLTApp,view=0..1);

Plot_2d