V3.html

Download Maple Worksheet

Theoretische Physik 3 für Lehramt L3

Quantenmechanik, Spezielle Relativitätstheorie und weitere Gebiete der Theoretischen Physik

Vorlesung gehalten an der J.W.Goethe-Universität in Frankfurt am Main (Wintersemester 2016/17)

von Prof. Dr.Dr.h.c. Horst Stöcker und Dr.phil.nat. Dr.rer.pol. Matthias Hanauske

Frankfurt am Main 17.10.2016

Erster Vorlesungsteil: Quantenmechanik

Kapitel I: 2.2) Ein Quantenteilchen im eindimensionalen Potentialtopf mit unendlich hohen Wänden

Ein Quantenteilchen im eindimensionalen Potentialtopf mit unendlich hohen Wänden

> restart:
with(plots):

Wir betrachten im folgenden einen quantenmechanischen Zustand eines Teilchens, welcher in einem Potentialtopf mit unendlich hohen Wänden gebunden ist und wir beschränken uns zunächst auf eine räumliche Dimension. Der Potentialtopf sei wie folgt definiert: V(x)=0 falls x=[0,a] und unendlich für x<0 und x>a. Da der Hamiltonoperator dieses Systems nicht von der Zeit abhängt, vereinfacht sich die Schrödingergleichung. Die Schrödingergleichung im Inneren des Potentialtopfes (0<= x <= a ) lautet:

> SGL:=diff(psi(x),x,x)=-2*m*E/hq^2*psi(x);
SGL:=diff(psi(x),x,x)=-k^2*psi(x):

(1.1)

Da der Potentialtopf an seinen Grenzen unendlich ist, muss die Wellenfunktion im Aussenbereich identisch verschwinden (psi(0)=0 und psi(a)=0). Wir arbeiten die erste Randbedingungen direkt in die allgemeine Lösung der Schrödingergleichung mit ein; sie besitz somit das folgende Aussehen (wobei k^2=2*m*E/hq^2 ):

> Loes:=subs({_C1=A},dsolve({SGL,psi(0)=0}));

(1.2)

Durch die zweite Randbedingungen (psi(a)=0) erhalten wir eine Quantisierungsvorschrift für die Wellenzahl k:

> _EnvAllSolutions:=true:
Quantk:=k=solve(subs(x=a,rhs(Loes))=0,k):
Quantk:=subs(_Z1=n,Quantk);
QuantE:=E=solve(subs({k=sqrt(2*m*E)/hq},Quantk),E);

(1.3)

Aufgrund dieser Quantisierungseigenschaft kann die Wellenzahl k und somit auch die Energie E des Quantenteilchens nur diskrete Werte annehmen.Setzen wir im folgenden z.B. hq=m=1, a=3, so können wir die Wellenfunktion und den Energieeigenwert des Quantenteilchens im Grundzustand (n=1) berechnen:

> n=1;
k[1]:=subs({n=1,a=3},rhs(Quantk));
E[1]:=subs({n=1,a=3,hq=1,m=1},rhs(QuantE));
psi[1]:=rhs(subs({k=k[1],A=A[1]},Loes));

(1.4)

Die noch unbekannte Amplitude lässt sich durch die Normierungsbedingung festlegen. Die Wellenfunktion des Quantenteilchens im Grundzustand besitz somit das folgende Aussehen:

> GLNorm:=int(conjugate(psi[1])*psi[1],x=0..3)=1;
A[1]:=solve(subs(conjugate(A[1])=A[1],GLNorm),A[1])[1];
plot(psi[1],x=0..3);

Plot_2d

Die Zustandsfunktionen der höherenergetischen Zustände berechnet man in gleicher Weise (n=1,2,3,4,....):

> restart:
with(plots):
SGL:=diff(psi(x),x,x)=-k^2*psi(x):
Loes:=subs({_C1=A},dsolve({SGL,psi(0)=0})):
_EnvAllSolutions:=true:
Quantk:=k=solve(subs(x=a,rhs(Loes))=0,k):
Quantk:=subs(_Z1=n,Quantk):
QuantE:=E=solve(subs({k=sqrt(2*m*E)/hq},Quantk),E):

> maxn:=10:
maxE:=subs({a=3,hq=1,m=1,n=maxn},rhs(QuantE)):
V:=piecewise(0 <= x and x<= a,0, x > a, infinity, x < 0, infinity):
GrenzeLinks:=implicitplot(x=0, x=-1..4, y=0..maxE, colour=red, thickness=3):
GrenzeRechts:=implicitplot(x=3, x=-1..4, y=0..maxE, colour=red, thickness=3):
GrenzeLinks1:=implicitplot(x=0, x=-1..4, y=-1..1, colour=red, linestyle=3, thickness=3):
GrenzeRechts1:=implicitplot(x=3, x=-1..4, y=-1..1, colour=red, linestyle=3, thickness=3):
PPot:=plot(subs(a=3,V),x=-1..4,thickness=3):
PPot:=display(PPot,GrenzeLinks,GrenzeRechts):
display(PPot):

for n from 1 by 1 to maxn do
k[n]:=subs({a=3},rhs(Quantk));
E[n]:=subs({a=3,hq=1,m=1},rhs(QuantE));
psi[n]:=rhs(subs({k=k[n],A=A[n]},Loes));

GLNorm:=int(conjugate(psi[n])*psi[n],x=0..3)=1;
A[n]:=solve(subs(conjugate(A[n])=A[n],GLNorm),A[n])[1];

PlotEnergie[n]:=plot(E[n],x=-0..3,thickness=5,color=black):
Plotpsi[n]:=plot(psi[n],x=0..3,thickness=2,color=blue):
Ani[n]:=display(Matrix(2,1,[display(GrenzeLinks1,GrenzeRechts1,Plotpsi[n],view=[-1..4,-1..1]),display(PPot,PlotEnergie[n])]));
od:

> display([seq(Ani[i],i=1..10)],insequence=true);

Plot_2d

Plot_2d

Ein Quantenteilchen im zweidimensionalen Potentialtopf mit unendlich hohen Wänden

> restart:
with(plots):

Wir betrachten im folgenden einen quantenmechanischen Zustand eines Teilchens, welcher in einem Potentialtopf mit unendlich hohen Wänden gebunden ist und wir beschränken uns zunächst auf zwei räumliche Dimension. Der Potentialtopf sei wie folgt definiert: V(x,y)=0 falls x=[0,a] und y=[0,b] und unendlich sonst. Da der Hamiltonoperator dieses Systems nicht von der Zeit abhängt, vereinfacht sich die Schrödingergleichung. Die Schrödingergleichung im Inneren des Potentialtopfes lautet:

> SGL:=diff(psi(x,y),x,x)+diff(psi(x,y),y,y)=-2*m*E/hq^2*psi(x,y);
SGL:=diff(psi(x,y),x,x)+diff(psi(x,y),y,y)=-k^2*psi(x,y):

(2.1)

Wir nehmen den folgenden Separationsansatz für die Zustandsfunktion psi an:

> psi(x,y)=psi[X](x)*psi[Y](y);
eval(subs(psi(x,y)=psi[X](x)*psi[Y](y),SGL));

(2.2)

Aufgrund des gewählten Ansatzes separiert auch die Schrödingergleichung in zwei voneinander unabhängige Gleichungen:

> SGLx:=diff(psi[X](x),x,x)=-k[X]^2*psi[X](x);
SGLy:=diff(psi[Y](y),y,y)=-k[Y]^2*psi[Y](y);

(2.3)

Wir lösen diese Gleichungen in gleicher Weise wie im eindimensionalen Fall. Da der Potentialtopf an seinen Grenzen unendlich ist, muss die Wellenfunktion im Außenbereich identisch verschwinden (psi(0,y)=0, psi(a,y)=0 und psi(x,0)=0, psi(x,b)=0 ). Wir arbeiten die Randbedingungen an den Grenzen x,y=0 direkt in die allgemeine Lösung der Schrödingergleichung ein; sie besitz somit das folgende Aussehen (wobei k^2=2*m*E/hq^2 ):

> Loesx:=subs({_C1=A},dsolve({SGLx,psi[X](0)=0}));
Loesy:=subs({_C1=1},dsolve({SGLy,psi[Y](0)=0}));
Loes:=psi(x,y)=rhs(Loesx)*rhs(Loesy);

(2.4)

Durch die Randbedingungen bei x=a bzw. y=b erhalten wir eine Quantisierungsvorschrift für die beiden Wellenzahlen kx und ky:

> _EnvAllSolutions:=true:
Quantkx:=k[X]=solve(subs(x=a,rhs(Loesx))=0,k[X]):
Quantkx:=subs(_Z1=n[X],Quantkx);
QuantEx:=E[X]=solve(subs({k[X]=sqrt(2*m*E[X])/hq},Quantkx),E[X]);
Quantky:=k[Y]=solve(subs(y=b,rhs(Loesy))=0,k[Y]):
Quantky:=subs(_Z2=n[Y],Quantky);
QuantEy:=E[Y]=solve(subs({k[Y]=sqrt(2*m*E[Y])/hq},Quantky),E[Y]);

(2.5)

Aufgrund dieser Quantisierungseigenschaft kann die Wellenzahl k und somit auch die Energie E des Quantenteilchens nur diskrete Werte annehmen. Setzen wir im folgenden z.B. hq=m=1, a=3, b=5, so können wir z.B. die Wellenfunktion und den Energieeigenwert des Quantenteilchens im Grundzustand (nx=1,ny=1) berechnen:

> n[X]=1;
n[Y]=1;
k[X][1]:=subs({n[X]=1,a=3},rhs(Quantkx));
E[X][1]:=subs({n[X]=1,a=3,hq=1,m=1},rhs(QuantEx));
k[Y][1]:=subs({n[Y]=1,b=5},rhs(Quantky));
E[Y][1]:=subs({n[Y]=1,b=5,hq=1,m=1},rhs(QuantEy));
psi[1,1]:=rhs(subs({k[X]=k[X][1],k[Y]=k[Y][1],A=A[1]},Loes));

(2.6)

Die noch unbekannte Amplitude lässt sich durch die Normierungsbedingung festlegen. Die Wellenfunktion des Quantenteilchens im Grundzustand besitz somit das folgende Aussehen:

> GLNorm:=int(int(conjugate(psi[1,1])*psi[1,1],x=0..3),y=0..5)=1;
A[1]:=solve(subs(conjugate(A[1])=A[1],GLNorm),A[1])[1];
Psi[1,1]=psi[1,1];

(2.7)

> with(StringTools):
Digits := 3:
Energie:=evalf(E[Y][1]+E[Y][1]):
Digits := 10:
Ptext1:=textplot3d([-1,0,0.3, Join(["E=",convert(Energie,string)])], align =RIGHT,color=black,font = [TIMES, ROMAN, 15]):
Ptext2:=textplot3d([-1,0,0.5, Join(["nx=",convert(1,string)])], align =RIGHT,color=black,font = [TIMES, ROMAN, 15]):
Ptext3:=textplot3d([-1,0,0.4, Join(["ny=",convert(1,string)])], align =RIGHT,color=black,font = [TIMES, ROMAN, 15]):
P11:=plot3d(psi[1,1],x=0..3,y=0..5,axes=framed):
display(P11,Ptext1,Ptext2,Ptext3,orientation=[-65, 50]);

Plot

Die Zustandsfunktionen der höherenergetischen Zustände berechnet man in gleicher Weise (n=1,2,3,4,....):

> restart:
with(plots):
with(StringTools):
SGLx:=diff(psi[X](x),x,x)=-k[X]^2*psi[X](x):
SGLy:=diff(psi[Y](y),y,y)=-k[Y]^2*psi[Y](y):
Loesx:=subs({_C1=A},dsolve({SGLx,psi[X](0)=0})):
Loesy:=subs({_C1=1},dsolve({SGLy,psi[Y](0)=0})):
Loes:=psi(x,y)=rhs(Loesx)*rhs(Loesy):
_EnvAllSolutions:=true:
Quantkx:=k[X]=solve(subs(x=a,rhs(Loesx))=0,k[X]):
Quantkx:=subs(_Z1=n[X],Quantkx):
QuantEx:=E[X]=solve(subs({k[X]=sqrt(2*m*E[X])/hq},Quantkx),E[X]):
Quantky:=k[Y]=solve(subs(y=b,rhs(Loesy))=0,k[Y]):
Quantky:=subs(_Z2=n[Y],Quantky):
QuantEy:=E[Y]=solve(subs({k[Y]=sqrt(2*m*E[Y])/hq},Quantky),E[Y]):

> maxnx:=5:
maxny:=5:
for nx from 1 by 1 to maxnx do
for ny from 1 by 1 to maxny do

k[X][nx]:=subs({n[X]=nx,a=3},rhs(Quantkx));
E[X][nx]:=subs({n[X]=nx,a=3,hq=1,m=1},rhs(QuantEx));
k[Y][ny]:=subs({n[Y]=ny,b=5},rhs(Quantky));
E[Y][ny]:=subs({n[Y]=ny,b=5,hq=1,m=1},rhs(QuantEy));
psi[nx,ny]:=rhs(subs({k[X]=k[X][nx],k[Y]=k[Y][ny],A=A[nx,ny]},Loes));
GLNorm:=int(int(conjugate(psi[nx,ny])*psi[nx,ny],x=0..3),y=0..5)=1;
A[nx,ny]:=solve(subs(conjugate(A[nx,ny])=A[nx,ny],GLNorm),A[nx,ny])[1];
Plotpsi:=plot3d(psi[nx,ny],x=0..3,y=0..5,axes=framed,numpoints=1500):

Digits := 3:
Energie:=evalf(E[Y][nx]+E[Y][ny]):
Digits := 10:
Ptext1:=textplot3d([-1,0,0.3, Join(["E=",convert(Energie,string)])], align =RIGHT,color=black,font = [TIMES, ROMAN, 15]):
Ptext2:=textplot3d([-1,0,0.5, Join(["nx=",convert(nx,string)])], align =RIGHT,color=black,font = [TIMES, ROMAN, 15]):
Ptext3:=textplot3d([-1,0,0.4, Join(["ny=",convert(ny,string)])], align =RIGHT,color=black,font = [TIMES, ROMAN, 15]):
Ani[nx,ny]:=display(Plotpsi,Ptext1,Ptext2,Ptext3);

od;
od;

> display([seq(seq(Ani[i,j],i=1..maxnx),j=1..maxny)],insequence=true,orientation=[-65, 50]);

Plot